Linux 内核学习笔记：内核引导程序之“setup.s”

2016-02-18

本文主要分析 Linux 0.11 内核引导程序setup.s关键部分。《Linux 内核完全注释》和《Linux 内核设计的艺术》两书将作为主要参考资料。

setup 模块已由 bootsect 模块加载至 0x90200 处，并且指令指针已指向该位置（boot/bootsect.s -> jmpi 0,SETUPSEG）。需要注意的是，setup 模块目前仍工作在实模式。

加载机器系统数据

setup 模块首先是将机器系统数据加载到内存 0x90000~0x901FD 区域（510B）即原 bootsect 模块所在地方（0x90000~0x901FF，共 512B）。这样就覆盖了原 bootsect 模块，并且只有 2 个字节没有使用到（512B - 510B）。具体代码如下：

! It is written in Intel 8086 Assembly. Added by MAX. 

！boot/setup.s ----------------------------------------------
entry start
start:

! ok, the read went well so we get current cursor position and save it for
! posterity.

	mov	ax,#INITSEG	! this is done in bootsect already, but...
	mov	ds,ax
	mov	ah,#0x03	! read cursor pos
	xor	bh,bh
	int	0x10		! save it in known place, con_init fetches
	mov	[0],dx		! it from 0x90000.

......
! Get hd0 data

	mov	ax,#0x0000
	mov	ds,ax
	lds	si,[4*0x41]
	mov	ax,#INITSEG
	mov	es,ax
	mov	di,#0x0080
	mov	cx,#0x10
	rep
	movsb

! Get hd1 data

	mov	ax,#0x0000
	mov	ds,ax
	lds	si,[4*0x46]
	mov	ax,#INITSEG
	mov	es,ax
	mov	di,#0x0090
	mov	cx,#0x10
	rep
	movsb

！boot/bootsect.s ----------------------------------------------
.org 508	! 508 即为 0x1FC，当前段是 0x9000，所以地址是 0x901FC
root_dev:
	.word ROOT_DEV

以上代码执行结果可用表表示如下：
图片来源：《Linux 内核设计的艺术》

注：关于上述代码的几个知识点

lds (Load pointer using DS 或 Load Data Segment Register)：传送目标指针，把指针内容装入 ds 和 si。如 lds si,string 把 string 段地址:偏移地址存到 ds:si。类似的还有 les、lfs 等。
硬盘参数表
在计算机 BIOS 设定的中断向量表中，int 0x41 的中断向量位置（4*0x41=0x0000:0x0104）存放的并不是中断服务程序的地址，而是第一个硬盘的基本参数列表。第二个硬盘的基本参数列表入口地址存放于 int 0x46 中断向量位置处（4*0x46=0x0000:0x0118）。硬盘参数表内容如下表所示：
图片来源：《Linux 内核完全注释》

关中断并复制 system 模块

关中断

在加载完机器系统数据后、进入保护模式前，首先要做的就是关中断：

1
2
3

! It is written in Intel 8086 Assembly. Added by MAX. 

	cli			! no interrupts allowed !

这意味着，在接下来的程序执行当中，无论是否发生中断，系统都不会对中断进行响应，除非中断重新开启（sti）。

对于 cli 和 sti，《Linux 内核设计的艺术》一书有一个详细的阐述：

关中断（cli）和开中断（sti）操作将在操作系统代码中频繁出现，其意义深刻。慢慢的你会发现，cli、sti 总是在一个完整操作过程的两头出现，目的是避免中断在此期间的介入。接下来的代码将为操作系统进入保护模式做准备。此处即将进行实模式下中断向量表（IVT）和保护模式下中断描述符表（IDT）的交接工作。试想，如果没有 cli，又恰好发生中断，如用户不小心碰了一下键盘，中断就要切进来，就不得不面对实模式的中断机制已经废除、保护模式的中断机制尚未完成的尴尬局面，结果就是系统崩溃。cli、sti 保证了这个过程中，IDT 能够完整创建，以避免不可预料中断的进入造成 IDT 创建不完整或新老中断机制混用。

复制 system 模块

接下来，setup 模块将 system 模块从 0x10000 复制到内存起始位置 0x00000 处：

! It is written in Intel 8086 Assembly. Added by MAX. 
! first we move the system to it's rightful place

	mov	ax,#0x0000
	cld			! 'direction'=0, movs moves forward
do_move:
	mov	es,ax		! destination segment
	add	ax,#0x1000
	cmp	ax,#0x9000
	jz	end_move
	mov	ds,ax		! source segment
	sub	di,di
	sub	si,si
	mov 	cx,#0x8000
	rep
	movsw
	jmp	do_move

! then we load the segment descriptors

end_move:
	......

其中，每次拷贝 0x8000 个字，也即 0x8000 * 2 = 0x10000 个字节。

这个复制操作将 BIOS 中断向量表和 BIOS 数据区完全覆盖，使它们不复存在。直到新的中断服务体系构建完毕之前，操作系统不再具备响应并处理中断的能力。

设置中断描述符表和全局描述符表

关于中断描述符表和全局描述符表基础知识，可先参考之前两篇博文：

设置中断描述符表和全局描述符表代码如下：

! It is written in Intel 8086 Assembly. Added by MAX.
end_move:
	mov	ax,#SETUPSEG	! right, forgot this at first. didn't work :-)
	mov	ds,ax
	lidt	idt_48		! load idt with 0,0
	lgdt	gdt_48		! load gdt with whatever appropriate
......
gdt:
	.word	0,0,0,0		! dummy

	.word	0x07FF		! 8Mb - limit=2047 (2048*4096=8Mb)
	.word	0x0000		! base address=0
	.word	0x9A00		! code read/exec
	.word	0x00C0		! granularity=4096, 386

	.word	0x07FF		! 8Mb - limit=2047 (2048*4096=8Mb)
	.word	0x0000		! base address=0
	.word	0x9200		! data read/write
	.word	0x00C0		! granularity=4096, 386

idt_48:
	.word	0			! idt limit=0
	.word	0,0			! idt base=0L

gdt_48:
	.word	0x800		! gdt limit=2048, 256 GDT entries
	.word	512+gdt,0x9	! gdt base = 0X9xxxx	! 这里要加上 gdt，即全局描述符表的在 setup 模块中的偏移地址；再加上 setup 模块
							! 自身的地址 0x90200，就能够得到全局描述符表的内存地址

其中，重点解释如下：

lidt 和 lgdt：这两个命令分别用于加载中断描述符表寄存器（IDTR）和全局描述符表寄存器（GDTR），操作数（idt_48 和 gdt_48）均为 6 个字节（即 48 位，因 IDTR 和 GDTR 长度均为 48 位）。操作数的 0~~1 字节用于表示描述符表的长度，2~~5 字节用于表示描述符表的 32 位线性基地址。
gdt：表示全局描述符表的内容，每项描述符均长 8 字节（即 64 位）。在这里，全局描述符表的第 0 项（dummy）不用，第 1 项是内核代码段描述符，第 2 项是内核数据段描述符。

设置中断描述符表和全局描述符表过程可用图表示如下：
图片来源：《Linux 内核设计的艺术》

上图 GDTR 的基地址”512+GDT”中的 GDT 表示的是 gdt 在 setup 模块中的偏移地址（在 setup.s 中即 205）。这里很容易误解为新建的全局描述符表会“覆盖” setup 模块从 gdt 开始的内容。其实，由 setup.s 编译而成的 setup 模块从 gdt 开始处本就存放着全局描述符表，而 GDTR 只是指向该处而已。可见于本文最后的 setup 模块执行完后内存映像图。

打开 A20

打开 A20，意味着 CPU 可以进行 32 位寻址，最大寻址空间为 4GB。这部分代码如下：

! It is written in Intel 8086 Assembly. Added by MAX.
! that was painless, now we enable A20

	call	empty_8042
	mov	al,#0xD1		! command write
	out	#0x64,al
	call	empty_8042
	mov	al,#0xDF		! A20 on
	out	#0x60,al
	call	empty_8042
......
empty_8042:
	.word	0x00eb,0x00eb
	in	al,#0x64	! 8042 status port
	test	al,#2		! is input buffer full?
	jnz	empty_8042	! yes - loop
	ret

虽然 Linux 0.11 只能支持 16MB 的物理内存，但其线性寻址空间已经是不折不扣的 4GB。

重新编程中断控制器 8259A

这部分代码为：

! It is written in Intel 8086 Assembly. Added by MAX.
! well, that went ok, I hope. Now we have to reprogram the interrupts :-(
! we put them right after the intel-reserved hardware interrupts, at
! int 0x20-0x2F. There they won't mess up anything. Sadly IBM really
! messed this up with the original PC, and they haven't been able to
! rectify it afterwards. Thus the bios puts interrupts at 0x08-0x0f,
! which is used for the internal hardware interrupts as well. We just
! have to reprogram the 8259's, and it isn't fun.

	mov	al,#0x11		! initialization sequence
	out	#0x20,al		! send it to 8259A-1
	.word	0x00eb,0x00eb		! jmp $+2, jmp $+2
	out	#0xA0,al		! and to 8259A-2
	.word	0x00eb,0x00eb
	mov	al,#0x20		! start of hardware int's (0x20)
	out	#0x21,al
	.word	0x00eb,0x00eb
	mov	al,#0x28		! start of hardware int's 2 (0x28)
	out	#0xA1,al
	.word	0x00eb,0x00eb
	mov	al,#0x04		! 8259-1 is master
	out	#0x21,al
	.word	0x00eb,0x00eb
	mov	al,#0x02		! 8259-2 is slave
	out	#0xA1,al
	.word	0x00eb,0x00eb
	mov	al,#0x01		! 8086 mode for both
	out	#0x21,al
	.word	0x00eb,0x00eb
	out	#0xA1,al
	.word	0x00eb,0x00eb
	mov	al,#0xFF		! mask off all interrupts for now
	out	#0x21,al
	.word	0x00eb,0x00eb

对这部分，《Linux 内核设计的艺术》有一个比较详细的说法：

CPU 在保护模式下，int 0x00~~0x1F 被 Intel 保留作为内部（不可屏蔽）中断和异常中断。如果不对 8259A 进行重新编程，int 0x00~~0x1F 将被覆盖。例如，IRQ0 （时钟中断）为 8 号（int 0x08）中断，但在保护模式下此中断号是 Intel 保留的“Double Fault”（双重故障）。因此，必须对 8259A 编程将原来的 IRQ0x00~~IRQ0x0F 对应的中断号重新分布，即在保护模式下，IRQ0x00~~IRQ0x0F 的中断号是 int 0x20~int 0x2F。

这一过程可用图表示如下：
图片来源：《Linux 内核设计的艺术》

设置处理器工作方式为保护模式并跳转至内存 0x0000 0000 处开始执行

在之前博文 Linux 内核学习笔记：预备知识之“寄存器模型”我们有介绍了 CR0 寄存器。要让处理器工作模式从实模式转变为保护模式，需要将 CR0 的 PE 置 1。在处理器工作模式转变为保护模式后，指令指针需指向至内存 0x0000 0000 （32 位）处，以从 head 程序（system 模块最前边部分）开始执行。这部分代码如下：

! It is written in Intel 8086 Assembly. Added by MAX.
! Well, now's the time to actually move into protected mode. To make
! things as simple as possible, we do no register set-up or anything,
! we let the gnu-compiled 32-bit programs do that. We just jump to
! absolute address 0x00000, in 32-bit protected mode.

	mov	ax,#0x0001	! protected mode (PE) bit
	lmsw	ax		! This is it!
	jmpi	0,8		! jmp offset 0 of segment 8 (cs)

其中，重点解释如下：

lmsw (Load Machine Status Word)：将 CR0 的 PE 置 1。
jmpi 0,8：因为处理器已经工作在保护模式，所以 jmpi 中的“段基址” 8 不再表示实模式下的段基址，而是保护模式下的段选择子。按照段选择子数据格式，8 （二进制形式为 0000 0000 0000 1000）表示该段选择子请求特权级为 0 （RPL=00）、所指向的描述符存放在 GDT （TI=0）、所指向的描述符索引为 1（DI=0000 0000 0000 1）。所以，这一句汇编表示的是“选择 GDT 中的 1 号描述符，并根据该描述符内容和偏移（jmpi 0,8）跳转至内存某一位置”。这个过程可用图表示如下：
图片来源：《Linux 内核设计的艺术》

而 GDT 第一项描述符的内容（如下图所示）说明了代码是从段基址 0x0000 0000、偏移为 0 处，也就是 head 程序的开始位置开始执行的。这意味着执行 head 程序。
图片来源：《Linux 内核设计的艺术》

setup 模块执行完后内存映像

setup 模块执行完后内存映像图如下所示：
图片来源：《Linux 内核完全注释》